Instruction:
1. Put the file in your sauerbraten-folder
2. Put a line "exec treecomplete.cfg" in your autoexec.cfg

What you get: tab-completion for all skyboxes and cfg-files in your sauerbraten folder, even non-default files that are not included in the official release.

greez viruz.

License is the 3-clause FreeBSD license, so do with it what you want.

alias searchfolders ".";
alias skyboxlist "";
alias execlist "";


append = [
	$arg1 = (concat (getalias $arg1) $arg2); 
]
treecomplete = [
	alias tempfolders ""
	looplist i $searchfolders [
		loopfiles f $i "" [
			alias filepath (concatword $i "/" $f)
			filepath = (strreplace $filepath "./" "");
			if (> (strstr $filepath "_ft.") -1) [
				filepath = (strreplace $filepath "packages/" "");
				filepath = (substr $filepath 0 (strstr $filepath "_ft."));
				append skyboxlist $filepath
			] 
			if (> (strstr $filepath ".cfg") -1) [
				append execlist $filepath
			] 
			if (= (strstr $f ".") -1) [
				tempfolders = (concat $tempfolders $filepath);
			] 
		]
	]
	searchfolders = $tempfolders;
	if (= (listlen $searchfolders) 0) [
		listcomplete skybox $skyboxlist
		listcomplete loadsky $skyboxlist
		listcomplete exec $execlist
	] [
		sleep 50 treecomplete
	]
]
treecomplete