bind O [showgui favserv]
editbind O [showgui favserv]

createine = [if (=s (getalias $arg1) "") [$arg1 = $arg2]]

createine _f_servers 5
looplist p "serv ip port" [
	loop i 15 [
		do [createine _f_@@p@i]
	]
]

newgui favserv [
	guititle "^f2Select your favorite server to connect"
	guibar
	loop i $_f_servers [
		do [
			if (&& (!=s $_f_serv@i "") (!=s $_f_ip@i "")) [
				guibutton (concat "Connect to^f2" $_f_serv@@i) [
					connect $_f_ip@@@i $_f_port@@@i
				] cube
			]
		]
	]
	guinoautotab [
		guitab "Config"
		guistayopen [
			guilist [
				guilist [
					guititle "^f2Server Name"
					guibar
					loop i $_f_servers [
						guilist [
							guibutton "" [
								looplist p "serv ip port" [
									do [_f_@[p]@@@i = ""]
								]
							] exit
							guifield _f_serv@i 20
						]
					]
				]
				guibar
				guilist [
					guititle "^f2Address"
					guibar
					loop i $_f_servers [
						do [
							guifield _f_ip@i 20 [
								if (=s $_f_ip@@i "") [
									_f_ip@@@i = (? (isconnected) (connectedip))
								]
							]
						]
					]
				]
				guibar
				guilist [
					guititle "^f2Port"
					guibar
					loop i $_f_servers [
						do [
							guifield _f_port@i 5 [
								if (=s $_f_port@@i "") [
									_f_port@@@i = (? (isconnected) (connectedport) 28785)
								]
							]
						]
					]
				]
			]
			guititle
			guilist [
				if (< $_f_servers 15) [
					guibutton "Add Server" [
						_f_servers = (min 15 (+ $_f_servers 1))
					]
				]
				guispring
				if (> $_f_servers 5) [
					guibutton "Remove Server" [
						_f_servers = (max 5 (- $_f_servers 1))
					]
				]
			]
		]
	]
] "Join Server"